撰寫/攝影	郭俊廷
難度	★★☆☆☆
材料表	空氣品質監測基本材料包(使用LinkIt™ 7697)

首先先看我們使用的材料跟完成品是甚麼樣子

組裝前

組裝後

1.使用材料

我們使用的材料有以下材料需要購買的空氣品質監測基本材料包(使用LinkIt™ 7697)（欲購買，請洽機器人王國）

LinkIt™ 7697開發板 *1
LinkIt™ 7697 NANO 擴充板 *1
Micro USB線 *1
5V 2.1A USB充電器 x 1
攀藤 G5 PMS5003 粉塵濃度感測器(已改成杜邦母座) *1
按鈕模組 *1
0.96 吋 OLED液晶螢幕模組 *1
科易KEYES DHT11温濕度感測器 *1
3pin杜邦線 27CM*2
彩色母母杜邦線20CM *10
束線帶 *3
空氣盒子外殼壓克力 *6
螺絲、螺帽、塑膠柱零件包 *1

螺絲、螺帽、塑膠柱零件包包含以下之數量:

M2*6塑膠螺絲*4
M2*6塑膠柱*4
M2塑膠螺帽*4
M2*10十字螺絲*4
M3*12十字螺絲*4
M3螺帽*4
M3*6塑膠柱*8
M3*6十字塑膠螺絲*8
M3塑膠螺帽*8

2.接線說明

LinkIt™ 7697 NANO 擴充板與攀藤 PMS5003 粉塵濃度感測器接線表、接線圖

LinkIt™ 7697 NANO 擴充板	攀藤 PMS5003 粉塵濃度感測器
5V	VCC(紫色)
GND	GND(橘色)
D2	TX(綠色)
D3	RX(藍色)

LinkIt™ 7697 NANO 擴充板與按鈕模組接線表、接線圖

LinkIt™ 7697 NANO 擴充板	按鈕模組
5V	VCC
GND	GND
D7	S

LinkIt™ 7697 NANO 擴充板與DHT11温濕度感測器接線表、接線圖

LinkIt™ 7697 NANO 擴充板	DHT11温濕度感測器
5V	VCC
GND	GND
D5	S

LinkIt™ 7697 NANO 擴充板與OLED液晶螢幕模組接線表、接線圖

LinkIt™ 7697 NANO 擴充板	攀藤 PMS5003 粉塵濃度感測器
VCC	VCC
GND	GND
SDA	SDA
SCL	SCL

3.程式說明

使用軟體為BlocklyDuino裡內建的arduino-1.8.5，此版本已把相關函式庫預先下載好，不需再另外下載相關函式庫套件。

只需下載並安裝 CP2102N 驅動程式。相關下載點及安裝說明請參考以下網址。

https://docs.labs.mediatek.com/linkit-7697-blocklyduino/v3-12883405.html

https://github.com/MediaTek-Labs/BlocklyDuino-for-LinkIt/releases/tag/3.0.312b

開啟BlocklyDuino裡內建的arduino-1.8.5即可編譯並燒錄程式。(位置如下圖)

沒有MCS版的程式

#include "PMS.h"
#include  <SoftwareSerial.h>
#include "U8g2lib.h"
#include <DHT.h>
#include <LWiFi.h>
#include "MCS.h"


SoftwareSerial PMSSerial(2, 3); //設定7697RX,TX腳位。接到PMS5003的TX,RX
PMS pms(PMSSerial);
PMS::DATA data;
U8G2_SSD1306_128X64_NONAME_1_HW_I2C u8g2(U8G2_R0, /* reset=*/ U8X8_PIN_NONE);

unsigned long time_1 = 0;

int pms1_0, pms2_5, pms10_0;
int t;
int h;
int D7;
DHT dht11_p5(5, DHT11);  //定義dht11腳位在P5



void setup()
{
  pinMode(7, INPUT);
  dht11_p5.begin();
  Serial.begin(9600);
  PMSSerial.begin(9600);
  u8g2.begin();
  u8g2.setFont(u8g2_font_6x10_tf);
  u8g2.setFontRefHeightExtendedText();
  u8g2.setDrawColor(1);
  u8g2.setFontPosTop();
  u8g2.setFontDirection(0);

}

void loop()
{
  D7 = digitalRead(7);
  t = dht11_p5.readTemperature();
  h = dht11_p5.readHumidity();
 
  

  while (!pms.read(data)) {}      //PM2.5開始讀取資料
  pms1_0 = data.PM_AE_UG_1_0;
  pms2_5 = data.PM_AE_UG_2_5;
  pms10_0 = data.PM_AE_UG_10_0;
  Serial.print("PM 1.0 (ug/m3): ");
  Serial.println(pms1_0);
  Serial.print("PM 2.5 (ug/m3): ");
  Serial.println(pms2_5);
  Serial.print("PM 10.0 (ug/m3): ");
  Serial.println(pms10_0);
  Serial.println("溫度:");
  Serial.println(t);
  Serial.println("濕度:");
  Serial.println(h);
  if (D7 == HIGH) {
    u8g2.firstPage();
    do {
      u8g2.setFont(u8g2_font_8x13_mf);
      u8g2.drawStr(15, 0, String("CAVE_AIR_BOX").c_str());
      u8g2.drawStr(0, 15, String(String() + "PM2.5:  " + pms2_5 + "ug/m3").c_str());
      u8g2.drawStr(0, 30, String(String() + "TEMP:   " + t + "C").c_str());
      u8g2.drawStr(0, 45, String(String() + "HUMID:  " + h + "%").c_str());
    } while (u8g2.nextPage());
    //delay(1000);
  } else {
    u8g2.clearDisplay();
  }


}

有使用MCS版本的程式(需要輸入自己的WiFi帳號密碼、MCS的ID跟KEY，建立自己的MCS通道)

#include "PMS.h"
#include  <SoftwareSerial.h>
#include "U8g2lib.h"
#include <DHT.h>
#include <LWiFi.h>
#include "MCS.h"
#define  MCS_INTERVAL_TIME 30000  //設定MCS多少秒傳一次資料

SoftwareSerial PMSSerial(2, 3); //設定7697RX,TX腳位。接到PMS5003的TX,RX
PMS pms(PMSSerial);
PMS::DATA data;
U8G2_SSD1306_128X64_NONAME_1_HW_I2C u8g2(U8G2_R0, /* reset=*/ U8X8_PIN_NONE);

unsigned long time_1 = 0;

int pms1_0, pms2_5, pms10_0;
int t;
int h;
int D7;
DHT dht11_p5(5, DHT11);  //定義dht11腳位在P5

/***************WIFI帳號密碼******************************/
char _lwifi_ssid[] = "自己的WiFi帳號";            //填入自己的WiFi帳號
char _lwifi_pass[] = "自己的WiFi密碼";              //填入自己的WiFi密碼
/********************************************************/


/***********MCS DeviceId、DeviceKey***********************/
MCSDevice mcs("DeviceId", "DeviceKey"); //需改成自己的MCS (DeviceId，DeviceKey)
/*********************************************************/

/************MCS通道**************************************/
MCSDisplayInteger temp("temp");
MCSDisplayInteger humid("humid");
MCSDisplayInteger PM25("PM25");
/*********************************************************/

void setup()
{
  pinMode(7, INPUT);
  dht11_p5.begin();
  Serial.begin(9600);
  PMSSerial.begin(9600);
  u8g2.begin();
  u8g2.setFont(u8g2_font_8x13_mf);
  u8g2.setFontRefHeightExtendedText();
  u8g2.setDrawColor(1);
  u8g2.setFontPosTop();
  u8g2.setFontDirection(0);
  /************MCS通道**************************************/
  mcs.addChannel(temp);
  mcs.addChannel(humid);
  mcs.addChannel(PM25);
  /*********************************************************/
  Serial.println("WiFi開始連線");
  u8g2.firstPage();
  do {
    u8g2.drawStr(0, 0, String("WiFi Connecting.....").c_str());
  } while (u8g2.nextPage());
  while (WiFi.begin(_lwifi_ssid, _lwifi_pass) != WL_CONNECTED) {
    delay(1000);
  }
  Serial.println("WIFI連線成功");
  u8g2.firstPage();
  do {
    u8g2.drawStr(0, 15, String("WiFi Connected").c_str());
  } while (u8g2.nextPage());
  while (!mcs.connected()) {
    mcs.connect();
  }
  Serial.println("MCS連線成功");
  u8g2.firstPage();
  do {
    u8g2.drawStr(0, 30, String("MCS Connected").c_str());
  } while (u8g2.nextPage());
  delay(1000);


}

void loop()
{
  D7 = digitalRead(7);
  t = dht11_p5.readTemperature();
  h = dht11_p5.readHumidity();

  while (!mcs.connected()) {
    mcs.connect();
    if (mcs.connected()) {
      Serial.println("MCS Reconnected.");
      u8g2.firstPage();
      do {
        u8g2.drawStr(0, 30, String("MCS Reconnected").c_str());
      } while (u8g2.nextPage());
    }
  }


  while (!pms.read(data)) {}      //PM2.5開始讀取資料
  pms1_0 = data.PM_AE_UG_1_0;
  pms2_5 = data.PM_AE_UG_2_5;
  pms10_0 = data.PM_AE_UG_10_0;
  Serial.print("PM 1.0 (ug/m3): ");
  Serial.println(pms1_0);
  Serial.print("PM 2.5 (ug/m3): ");
  Serial.println(pms2_5);
  Serial.print("PM 10.0 (ug/m3): ");
  Serial.println(pms10_0);
  Serial.println("溫度:");
  Serial.println(t);
  Serial.println("濕度:");
  Serial.println(h);
  if (D7 == HIGH) {
    u8g2.firstPage();
    do {
      u8g2.setFont(u8g2_font_8x13_mf);
      u8g2.drawStr(15, 0, String("CAVE_AIR_BOX").c_str());
      u8g2.drawStr(0, 15, String(String() + "PM2.5:  " + pms2_5 + "ug/m3").c_str());
      u8g2.drawStr(0, 30, String(String() + "TEMP:   " + t + "C").c_str());
      u8g2.drawStr(0, 45, String(String() + "HUMID:  " + h + "%").c_str());
    } while (u8g2.nextPage());
    //delay(1000);
  } else {
    u8g2.clearDisplay();
  }
  mcs.process(100);

  if (millis() > time_1 + MCS_INTERVAL_TIME) {
    time_1 = millis();
    temp.set(t);
    humid.set(h);
    PM25.set(pms2_5);
  }

}

沒有使用MCS的載點：CAVEDU_AirBox_NOMCS.zip

有使用MCS的載點：CAVEDU_AirBox_MCS.zip