[LinkIt 7697 開發板] BLE藍牙簡介

本文要介紹聯發科技實驗室7697開發板的BLE藍牙4.0通訊機制，包含central、iBeacon 以及 peripheral 等三種角色。

LinkIt 7697的BLE

LinkIt 7697支援藍牙低功耗通訊協定Bluetooth Low Energy)，但不支援傳統的 profile 像是 Bluetooth BR 或 EDR。Bluetooth Low Energy 裝置可作為 central 或 peripheral 裝置。peripheral裝置(像是心跳計) 會把關於本身的資料廣播出去。central裝置則會尋找附近的peripheral裝置，並可進一步連到peripheral 來存取其屬性，例如服務(service)或特徵(chracteristic)。

*BLE peripheral 與 Central   001

LinkIt 7697 提供了以下 Arduino 函式庫類別：

• LBLE：用來初始化 Bluetooth Low Energy子系統subsystem
• LBLECentral：提供central裝置的基本功能，例如掃描鄰近的peripheral
• LBLEPeripheral：提供peripheral裝置的基本功能：
  • 設定advertisement package
  • 設定 characteristic與service(UUID).

7697 可用作 Central、iBeacon 以及 peripheral，請看以下介紹：

7697作為Central

7697的LBLE 函式庫可讓 7697 成為一個central裝置來掃描附近的BLE裝置。如以下程式中的scanner：

LBLE.begin();
while(!LBLE.ready())
{
delay(10);
}
Serial.println(“BLE ready”);

//開始掃瞄鄰近的廣播資料
LBLECentral scanner;
scanner.scan();

呼叫scan()之後，central裝置就會不斷蒐尋附近的Blueotooth裝置，掃描結果會更新在LBLECentral類別，後續可呼叫 getPeripheralCount() 來取得掃瞄到的 peripheral 裝置數量。

for(int i = 0; i < scanner.getPeripheralCount(); ++i)
{
Serial.println(scanner.getName(i));
}

請注意藍牙 peripheral 的廣播內容會因不同的裝置而異，例如，一台 iBeacon 裝置丟出來資料可能會有 connectivity flag 以及製造商資料，但心跳計則可能包含 service UUID 與裝置名稱。

常見的情境是 central 去掃描附近的 iBeacon 裝置，在此會用到兩個方法：isIBeacon 與 getIBeaconInfo，用來解析iBeacon廣播資料相當好用。有掃到裝置的話，就可由Arduino IDE 的 serial monitor 畫面看到該裝置的基本資料。

File > Examples > LBLE > ScanPeripherals

#include <LBLE.h>
#include <LBLECentral.h>

LBLECentral scanner;

void setup() {
  Serial.begin(9600);

  //初始化BLE
  Serial.println("BLE begin");
  LBLE.begin();
  while (!LBLE.ready()) {
    delay(10);
  }
  Serial.println("BLE ready");

  //開始掃瞄鄰近的廣播資料
  scanner.scan();
}

void printDeviceInfo(int i) {
  Serial.print("Addr: ");
  Serial.println(scanner.getAddress(i));
  Serial.print("RSSI: ");
  Serial.println(scanner.getRSSI(i));
  Serial.print("Name: ");
  Serial.println(scanner.getName(i));
  Serial.print("UUID: ");
  if (!scanner.getServiceUuid(i).isEmpty()) {
    Serial.println(scanner.getServiceUuid(i));
  } else {
    Serial.println();
  }
  Serial.print("Flag: ");
  Serial.println(scanner.getAdvertisementFlag(i), HEX);
  Serial.print("Manu: ");
  Serial.println(scanner.getManufacturer(i));

  if (scanner.isIBeacon(i)) {
    LBLEUuid uuid;
    uint16_t major = 0, minor = 0;
    uint8_t txPower = 0;
    scanner.getIBeaconInfo(i, uuid, major, minor, txPower);

    Serial.println("iBeacon->");
    Serial.print("    UUID: ");
    Serial.println(uuid);
    Serial.print("    Major: ");
    Serial.println(major);
    Serial.print("    Minor: ");
    Serial.println(minor);
    Serial.print("    txPower: ");
    Serial.println(txPower);
  }
}

void loop() {
  delay(3000);

  //顯示找到的peripheral裝置
  Serial.println(scanner.getPeripheralCount());
  for (int i = 0; i < scanner.getPeripheralCount(); ++i) {
    Serial.println("---");
    printDeviceInfo(i);
  }

  Serial.println("----------------------");
}

7697作為iBeacon

iBeacon是一個只會廣播(advertise)資料的BLE裝置，廣播的資料格式可以自訂。請注意做為 iBeacon 的 BLE 裝置無法被連接。

請用LBLEAdvertisement類別就能產生所需的iBeacon廣播資料。並可呼叫configAsIBeacon方法將廣播資料設定為iBeacon格式，如以下程式碼所示：

LBLEAdvertisementData beaconData;
beaconData.configAsIBeacon(“E2C56DB5-DFFB-48D2-B060-D0F5A71096E0”, 01, 02, -40);

• E2C56DB5-DFFB-48D2-B060-D0F5A71096E0是您的 iBeacon UUID。這個值您可以自行產生。E2C56DB5-DFFB-48D2-B060-D0F5A71096E0因為是iOS AirLocate iBeacon example 中所用的UUID，因此許多 iOS 工具程式都有內建設定來搜尋這組UUID。
• 01與02是 major ID 與 minor ID，可用來區別不同的iBeacon裝置。例如，您可能會在會議室或辦公室放置多台7697。您可把 major number 設為樓層，minor number 則是房間編號等。這樣一來iBeacon scanner只要透過這兩個數字就能知道使用者現在是在哪一層樓的哪一間房間了。
• 最後一個數字Tx Power，-40，代表該裝置的發送功率。beacon scanner只要去比較這個數值與實際的訊號強度就能約略估算距離。實際的發送功率會根據天線設定方式而有異，所以建議這個數值要與 scanner 一併校正。

廣播資料設定完成之後，只要呼叫LBLEPeripheral的 advertise方法就能開始廣播資料：

LBLEPeripheral.advertise(beaconData);
LinkIt 7697 會馬上開始廣播資料，呼叫 stopAdvertise() 即可停止廣播。

7697 有現成的範例(BeaconAdvertisement)，您可運用Locate Beacon這類的 ibeacon 工具來搜尋。以下是這個 app 的搜尋畫面擷圖：

File > Examples > LBLE > BeaconAdvertisement

#include <LBLE.h>
#include <LBLEPeriphral.h>

void setup() {
  Serial.begin(9600);

  //初始化BLE
  Serial.println("BLE begin");
  LBLE.begin();
  while (!LBLE.ready()) {
    delay(100);
  }
  Serial.println("BLE ready");

  //將廣播資料設定為iBeacon.
  LBLEAdvertisementData beaconData;

  //以下是AirLocate通用的UUID.
  LBLEUuid uuid("E2C56DB5-DFFB-48D2-B060-D0F5A71096E0");
  beaconData.configAsIBeacon(uuid, 01, 02, -40);

  Serial.print("Start advertising iBeacon with uuid=");
  Serial.println(uuid);

  //開始廣播
  LBLEPeripheral.advertise(beaconData);
}

void loop() {
  // The underlying framework will advertise periodically.
  // we simply wait here.
  // You can use iBeacon apps such as
  // "Locate Beacon" by Radius Networks on iOS devices to locate this beacon.
  delay(3000);
}

7697作為peripheral

第三種應用是將 7697 作為周邊，這時我們就能從別的裝置去連接它。這也是CAVEDU之前在使用LinkIt ONE較常用的方式，搭配手機來與開發板互動。

peripheral device裝置上需要先建立一個 GATT 伺服器，才能讓其他的 BLE central 連到這個peripheral。GATT伺服器包含了一組屬性：service與characterstic。像是心跳帶這類的服務就是用UUID來區分。一個服務可能包含多個具有數值(value)的特徵(characteristic)，例如心跳帶服務就應該會有一個heart rate measurement value特徵。BLE central裝置就可以發送需求來讀寫這些數值。

關於GATT屬性，請參考Bluetooth.com 或 https://learn.adafruit.com/introduction-to-bluetooth-low-energy/gatt#services-and-characteristics

啟動GATT伺服器之前，需要定義這個服務以及我們要用到的特徵。由於服務與特徵都是永久性(persistent)，並且應該會被其他central裝置頻繁讀寫，在此把service與characteristic定義為global是比較好的做法，如下所示：

#include <LBLE.h>
#include <LBLEPeriphral.h>

//定義具備一個特徵GATT服務
LBLEService ledService(“19B10010-E8F2-537E-4F6C-D104768A1214”);
LBLECharacteristicInt switchCharacteristic(“19B10011-E8F2-537E-4F6C-D104768A1214”, LBLE_READ | LBLE_WRITE);

• 19B10010-E8F2-537E-4F6C-D104768A1214是服務UUID，可供其他central裝置尋找到它。
• 19B10011-E8F2-537E-4F6C-D104768A1214是特徵UUID。. GATT通訊協定會把特徵視為一個緩衝器，長度最大可到512位元組。 LBLECharacteristicInt可用來定義整數型別的特徵，您再用setValue() 去設定其整數參數即可，不必去動到緩衝器內部。

定義好服務與特徵之後，接著要定義它們的關係，再把這些服務加入peripheral裝置，如下所示：

void setup() {
//將特徵加入ledService
ledService.addAttribute(switchCharacteristic);

//將服務加入GATT伺服器(即一個 BLE peripheral)
LBLEPeripheral.addService(ledService);
使用以下語法來初始化GATT伺服器：

LBLEPeripheral.begin();
請注意一旦呼叫begin()之後，就無法加入更多service，也無法修改service與characteristic之間的關係了。

peripheral裝置現在已準備好由central裝置來連線，並可藉由isWritten()檢查特徵值是否有被外部裝置來修改：

File > Examples > LBLE > SimplePeripheral

為了安全性起見，裝置的addr 不會直接寫在板子上(當然也是有這麼做的)。本範例透過以下語法將 7697 addr 顯示於 serial monitor 中，您再修改 App Inventor 即可。

Serial.println(LBLE.getDeviceAddress());

#include <LBLE.h>
#include <LBLEPeriphral.h>

// Define a simple GATT service with only 1 characteristic
LBLEService ledService("19B10010-E8F2-537E-4F6C-D104768A1214");
LBLECharacteristicInt switchCharacteristic("19B10011-E8F2-537E-4F6C-D104768A1214", LBLE_READ | LBLE_WRITE);

void setup() {
  pinMode(LED_BUILTIN, OUTPUT);
  digitalWrite(LED_BUILTIN, LOW);

  Serial.begin(9600);

  //初始化BLE
  Serial.println("BLE begin");
  LBLE.begin();
  while (!LBLE.ready()) {
    delay(100);
  }
  Serial.println("BLE ready");
  Serial.print("device address is:");
  Serial.println(LBLE.getDeviceAddress()); //顯示7697 BLE addr

  //設定廣播資料
  // In this case, we simply create an advertisement that represents an
  // connectable device with a device name
  LBLEAdvertisementData advertisement;
  advertisement.configAsConnectableDevice("BLE LED");

  // Configure our device's Generic Access Profile's device name
  // Ususally this is the same as the name in the advertisement data.
  LBLEPeripheral.setName("BLE LED");

  // Add characteristics into ledService
  ledService.addAttribute(switchCharacteristic);

  // Add service to GATT server (peripheral)
  LBLEPeripheral.addService(ledService);

  //啟動GATT伺服器，此時已可被連線
  LBLEPeripheral.begin();

  //開始廣播
  LBLEPeripheral.advertise(advertisement);
}

void loop() {
  delay(100);
  if (switchCharacteristic.isWritten()) {
    const char value = switchCharacteristic.getValue();
    switch (value) {
      case '1':
        digitalWrite(LED_BUILTIN, HIGH); //7697就是D7, 其他Arduino為D13
        break;
      case '0':
        digitalWrite(LED_BUILTIN, LOW);
        break;
      default:
        break;
    }
  }
}

Android端(App Inventor)

要寫一個小程式來與7697互動，在此推薦使用App Inventor來編寫Android端程式，一方面是圖形化介面開發非常快，另一方面則是手機端有許多豐富的資源，可以讓您的專題更完整。別忘了參考CAVEDU所開發的App Inventor中文學習網喔！

請登入App Inventor (http://ai2.appinventor.mit.edu) 之後建立一個新的專案，或由此下載本範例所需之 .aia 檔

Designer 頁面

本範例用到的元件有多個按鈕、顯示訊息用的 Labe; 當然也需要用到最新的 BluetoothLE 元件。Designer 頁面完成如下圖，您只要做得差不多就好，不需要一模一樣。

Blocks 頁面

STEP1：

宣告 addr 變數，代表所要連線的7697 藍牙位址。

Screen1初始化時，要求 BluetoothLE元件開始掃瞄，連線成功的話會自動呼叫BluetoothLE.Connnected事件，並修改相關元件的設定。

STEP2：

按下連線按鈕時，根據按鈕的文字來決定要連線或斷線。您也可以使用兩個獨立的按鈕來做到這件事。

STEP3  ：

斷線時呼叫BluetoothLE事件，並將元件回復到初始狀態等候下一次連線。

STEP4  ：

按下按鈕時，透過 WriteIntValue 方法分別發送 1 與 0 出去，7697 接到這兩個整數值之後就會執行對應的動作。您可以依照這樣的架構加入更多按鈕或其他二元觸發條件（例如Google語音辨識、感測器值等等）。別忘了 7697 端也要加入更多case 來接收您新增的控制碼。

操作

請先上傳7697端的程式並開啟serial monitor來看看狀態，在此7697是一個peripheral。請點選App端的 Connect按鈕就會連線，連線成功即可點選ON/OFF按鈕（在連線成功之前不可按）來控制7697的 D7 USR LED燈亮滅。

相關文章：

• [App Inventor IoT ] Lesson 1: Arduino 101 LED Blink
• [App Inventor IoT ] Lesson 2: Arduino 101 LED fading (PWM)
• [App Inventor IoT ] Lesson 3: Read Arduino 101’s analog pin
• [App Inventor IoT ] Lesson 4: 4-axis robotarm
• [App Inventor IoT ] Lesson 5: Read DHT11 Temperature/Humidity Sensor